| 1 | #----------------------------------------------------------- |
|---|
| 2 | # Copyright Christian Arnault LAL-Orsay CNRS |
|---|
| 3 | # arnault@lal.in2p3.fr |
|---|
| 4 | # Modified by Grigory Rybkin |
|---|
| 5 | # See the complete license in cmt_license.txt "http://www.cecill.info". |
|---|
| 6 | #----------------------------------------------------------- |
|---|
| 7 | |
|---|
| 8 | # Remove spaces, if any |
|---|
| 9 | set _m="`uname -m`" |
|---|
| 10 | while ( "$_m" =~ "* *" ) |
|---|
| 11 | set _m="${_m:s/ //}" |
|---|
| 12 | end |
|---|
| 13 | setenv CMTBIN `uname`-"$_m" |
|---|
| 14 | unset _m |
|---|
| 15 | |
|---|
| 16 | if ( $?CMTCONFIG == 0 ) then |
|---|
| 17 | setenv CMTCONFIG `${CMTROOT}/mgr/cmt_system.sh` |
|---|
| 18 | endif |
|---|
| 19 | |
|---|
| 20 | if ( $?0 == 0 ) then |
|---|
| 21 | if ( $?tcsh == 1 ) then |
|---|
| 22 | source ${CMTROOT}/src/setup.tcsh |
|---|
| 23 | else if ( "${shell:t}" == "tcsh" ) then |
|---|
| 24 | source ${CMTROOT}/src/setup.tcsh |
|---|
| 25 | endif |
|---|
| 26 | endif |
|---|
| 27 | |
|---|
| 28 | # Remove CMT entries, if any |
|---|
| 29 | set newpath=() |
|---|
| 30 | foreach p (${path:q}) |
|---|
| 31 | if ( "${p}" !~ "*/CMT/*" ) then |
|---|
| 32 | if ( ${#newpath} != 0 ) then |
|---|
| 33 | set newpath=(${newpath:q} ${p:q}) |
|---|
| 34 | else |
|---|
| 35 | set newpath=(${p:q}) |
|---|
| 36 | endif |
|---|
| 37 | endif |
|---|
| 38 | end |
|---|
| 39 | |
|---|
| 40 | set path=(${newpath:q} "${CMTROOT}/${CMTBIN}") |
|---|
| 41 | unset newpath |
|---|
| 42 | |
|---|
| 43 | alias cmt '${CMTROOT}/${CMTBIN}/cmt.exe' |
|---|
| 44 | |
|---|
| 45 | if ( $?CLASSPATH == 0 ) then |
|---|
| 46 | setenv CLASSPATH ${CMTROOT}/java/cmt.jar |
|---|
| 47 | else if ( "${CLASSPATH}" == "" ) then |
|---|
| 48 | setenv CLASSPATH ${CMTROOT}/java/cmt.jar |
|---|
| 49 | else if ( "${CLASSPATH}" !~ "*/CMT/*" ) then |
|---|
| 50 | setenv CLASSPATH ${CLASSPATH}:${CMTROOT}/java/cmt.jar |
|---|
| 51 | else |
|---|
| 52 | # Remove CMT entries |
|---|
| 53 | set _p="${CLASSPATH}" |
|---|
| 54 | while ( "$_p" =~ "*:*" ) |
|---|
| 55 | set _p="${_p:s/:/ /}" |
|---|
| 56 | end |
|---|
| 57 | |
|---|
| 58 | set newpath= |
|---|
| 59 | foreach p (${_p}) |
|---|
| 60 | if ( "${p}" !~ "*/CMT/*" ) then |
|---|
| 61 | if ( "${newpath}" != "" ) then |
|---|
| 62 | set newpath=${newpath}:${p} |
|---|
| 63 | else |
|---|
| 64 | set newpath=${p} |
|---|
| 65 | endif |
|---|
| 66 | endif |
|---|
| 67 | end |
|---|
| 68 | |
|---|
| 69 | if ( "${newpath}" != "" ) then |
|---|
| 70 | setenv CLASSPATH ${newpath}:${CMTROOT}/java/cmt.jar |
|---|
| 71 | else |
|---|
| 72 | setenv CLASSPATH ${CMTROOT}/java/cmt.jar |
|---|
| 73 | endif |
|---|
| 74 | unset _p newpath |
|---|
| 75 | endif |
|---|
| 76 | |
|---|
| 77 | alias jcmt '(java cmt_parser)' |
|---|
| 78 | |
|---|
| 79 | # Set MAKEFLAGS, if unset (similar to NPROC with Plan 9 mk utility) |
|---|
| 80 | if ( $?MAKEFLAGS == 0 ) then |
|---|
| 81 | setenv MAKEFLAGS -j`getconf _NPROCESSORS_ONLN` || unsetenv MAKEFLAGS |
|---|
| 82 | if ( $?MAKEFLAGS == 1 ) then |
|---|
| 83 | setenv MAKEFLAGS "${MAKEFLAGS} QUICK=1" |
|---|
| 84 | else |
|---|
| 85 | setenv MAKEFLAGS "QUICK=1" |
|---|
| 86 | endif |
|---|
| 87 | endif |
|---|
