###############################################################
### Estimations pour PAON-1 (Interfero de test a Nancay )  ####
#######################  Avril 2012  ##########################
###############################################################

setaxesatt 'font=helvetica,bold,16 fixedfontsize minorticks'

##### 1ere partie ##############
#   Trace des radio sources a partir du catalog NVSS 
readfits nvss.fits 
plot2dw nvss C_RAJ2000/15. C_DEJ2000 S1_4 S1_4>5000  'nsta orange marker=circle,7'
plot2dw nvss C_RAJ2000/15. C_DEJ2000 S1_4 S1_4>10000  'nsta orange marker=fcircle,9 same'
plot2dw nvss C_RAJ2000/15. C_DEJ2000 S1_4 S1_4>20000  'nsta red marker=fcircle,11 same'
plot2dw nvss C_RAJ2000/15. C_DEJ2000 S1_4 S1_4>50000  'nsta blueviolet marker=fcircle,13 same'

settitle 'NVSS radio sources (flux>5 Jy)' ' '  'font=helvetica,bold,16'
setaxelabels 'RA (alpha) - hours' 'DEC (delta)' 'font=helvetica,bold,16'

set lines ( 'flux > 10 Jy' 'flux > 20 Jy' 'flux > 50 Jy' ) 
set cols ( orange red blueviolet )
textdrawer lines cols 'font=helvetica,bold,16 frame'
addtext 20. 62. 'CasA ~500 Jy'  'font=helvetica,bold,14 blueviolet'
addtext 17. 36. 'CygA ~800 Jy'  'font=helvetica,bold,14 blueviolet'

# Latitude 47 degres 
addline 0 44 24 44 'line=solid,1'
addline 0 50 24 50 'line=solid,1'

addline 0 67 24 67 'line=dotted,1'
addline 0 27 24 27 'line=dotted,1'

w2ps 
w2eps nvss_bright.eps

#############################################
########## 2eme partie ##############
### Calcul bruit et franges d'interference 
#############################################
#  Calcul bruit  
WDISH = 3.
lambda = 0.21
# Vitesse angulaire Omega en degre/second = 15./3600.*cos(delta)
OMEGA = cos(Pi*47./180)*15./3600.
set ANG $OMEGA*x
set T (2*M_PI*$WDISH/$lambda*sin(M_PI*$ANG/180.))
set XX ((fabs($T)<1e-8)?1.:(sin($T)/$T))
func $XX*$XX -1800 1800 240 

# Niveau de bruit en Jy 
TSYS = 100 
k_B = 1.38e-23 
A = 0.75*Pi*$WDISH*$WDISH/4. 
DNU = 5.e6
TINT = 15  
NOISE = 2*$k_B*$TSYS/$A/sqrt($DNU*$TINT)*1.e26 
echo 'NoiseLevel: ' $NOISE 'Jansky '


##### Calcul N-tuple avec Visib(temps) 

# Executer pour FLXSRC=500, NOISE=10 
del visi 
c++execfrf paon1.cc 
mv visi visi500
# Executer pour FLXSRC=20, NOISE=5  (4-5 d'integrations/transits) 
del visi 
c++execfrf paon1.cc 

mv visi visi20

#### Traces 
set titres ( '500 Jy - single transit (Noise=10 Jy)'  '20 Jy - 4 transits (Noise=3 Jy)' ) 
set O ( visi500 visi20 ) 
for i 0:2 
  newwin 1 2 
  plot2de $O[i] time vI 0. err*1.4 1 'marker=fcircle,5 cpts notit nsta'
  settitle "$titres[i]" ' ' 'font=helvetica,bold,16'
  setaxelabels 'Time (s)' 'Vis=I - Jy ' '  font=helvetica,bolditalic,14'
  plot2de $O[i] time vre 0. err 1 'marker=fcircle,5 red cpts notit nsta'
  setaxelabels 'Time (s)' 'Real[Vis] - Jy ' '  font=helvetica,bolditalic,14'
  w2ps 
end