source: Sophya/trunk/AddOn/TAcq/dspms.pic

#  Script affichage spectre moyennes fait par Monitoring
if ( $# < 2 ) then 
  echo ' dspms.pic/Erreur - Usage dspms Directory NumFile [BaseDir] ' 
  return 
endif
set dir $1
set numf $2

set bdir /Raid/PittsDec10
if ( $# > 2 ) then 
  set bdir $3
endif

delobjs *
# openppf /Raid/PittsDec10/$dir/meanspec$numf.ppf
set flnm $bdir/$dir/meanspec$numf.ppf
echo '------ Opening file ' $flnm 
openppf $flnm 
del myspec
mv spectre  myspec
set nchan ${myspec.nrows}
for i 0:$nchan
  del smV$i 
  objaoper myspec row $i smV$i
end

setaxesatt 'font=helvetica,bold,16 fixedfontsize minorticks'
zone 1

# set exfreq (n+2212)*250/4096+1250 
# set exfreq (n*250/4096+1250) 
##  Expression de la frequence pour FFT shrinke 
set exfreq ((n+2049)*250/4096+1250) 
plot2d smV0 $exfreq 10*log10(val) val>1.e-6 'black nsta cpts notit'
setaxelabels  ' Freq (MHz)' 'Spectra - dB' 'font=helvetica,bolditalic,16'
 
# set cols ( black darkviolet blue navyblue red orange yellow green )
set cols ( blue red green magenta black darkviolet navyblue orange yellow )

for i 1:${myspec.nrows}
  plot2d smV$i $exfreq 10*log10(val) val>1.e-6 "$cols[i] cpts nsta same"
end

if ( $nchan < 3 )  then 
  zny = $nchan
  znx = 1
else 
  if ( $nchan < 7 )  then 
    zny = $nchan/2
    znx = 2
   else 
    zny = 3
    znx = 3
  endif
endif

defscript dspec 
  zone $znx $zny 
  for i 0:$nchan
   disp smV$i "$cols[i]"
  end
endscript 

defscript dspeclg 
  zone $znx $zny 
  for i 0:$nchan
   disp smV$i "logy $cols[i]"
  end
endscript 

defscript dhval 
  zone $znx $zny 
  for i 0:$nchan
   disp hvalV$i "$cols[i]"
  end
endscript 

defscript dh2
  zone $znx $zny 
  for i 0:$nchan
   plot2d h2dV$i x y val>0 "notit nsta $cols[i]"
  end
endscript 

defscript dexpo
  zone $znx $zny 
  for i 0:$nchan
   disp hexpV$i "$cols[i]"
   n/plot hexpV$i.val%x val>0 ! "nsta same marker=fcircle,9 $cols[i]"
  end
endscript 

defscript dsatur
  zone $znx $zny 
  for i 0:$nchan
    imag saturV$i "zoomx40"
  end
endscript 

defscript dsatur2
  zone $znx $zny 
  for i 0:$nchan
    n/plot saturV$i.val%r+c r!=1||c!=1 ! "marker=fcircle,1 nsta $cols[i]"
    n/plot saturV$i.val%r+c (r!=1||c!=1)&&val>0.1 ! "marker=fcircle,9 nsta same $cols[i]"
  end
endscript

set lines ( B1.V1 B1.V2 B1.V3 B1.V4 B2.V1 B2.V2 B2.V3 B2.V4 )
textdrawer lines cols 'font=helvetica,bold,16'

# settitle 'Spectre 8 voies FFT - ScalingFactor=9' ' ' 'font=helvetica,bold,18'

newwin 
dspeclg 
newwin 
dspec 
newwin 
dhval
newwin 
dh2
newwin 
dexpo
newwin 
dsatur
newwin 
dsatur2

echo '----> use dspec dhval and  dh2 dexpo dsatur scripts to check value histograms'