source: Sophya/trunk/ArchTOIPipe/configure.in@ 2650

dnl Process this file with autoconf to produce a configure script.
AC_INIT(Kernel/toi.cc)
AC_CONFIG_HEADER(conf.h)

AC_ARG_WITH(sophya, [  --with-sophya           Compile and link with SOPHYA],
        use_sophya=1, use_sophya=0)

AC_SUBST(use_sophya)

AC_ARG_WITH(piolib, [ --with-piolib   Compile with PIOLib],
        use_piolib=1, use_piolib=0)
AC_SUBST(use_piolib)

if test `uname` = OSF1 -a -z "$CXX"; then
  if test -x /usr/bin/cxx; then
    echo "using cxx on alpha"
    CXX=cxx
    export CXX
  fi
fi

if test `uname` = IRIX64 -a -z "$CXX"; then
  if test -x /usr/bin/CC; then
    echo "using CC on IRIX"
    CXX=CC
    export CXX
  fi
fi

dnl on donne priorite a g++ sur c++ sur Linux
if test `uname` = Linux -a -f /usr/bin/g++; then
  CXX=g++
fi

AC_PROG_CC
AC_PROG_CXX
if test `uname` = "Darwin"; then
  AR=libtool
  ARFLAGS="-static -o"
  RANLIB=":"
  AC_SUBST(AR)
  AC_SUBST(ARFLAGS)
  AC_SUBST(RANLIB)
elif test `uname` = "IRIX64"; then
  AR=CC
  ARFLAGS="-ar -prelink -o"
  AC_SUBST(AR)
  AC_SUBST(ARFLAGS)
  RANLIB=":"
  AC_SUBST(RANLIB)
else
  ARFLAGS="-cr"
  AC_SUBST(ARFLAGS)
  if test -x /usr/bin/ar; then
    AC_PATH_PROG(AR, ar, /usr/bin/ar, /usr/bin:$PATH) 
  else
    AC_CHECK_PROG(AR, ar)
  fi
  if test -x /usr/bin/ranlib; then
    AC_PATH_PROG(RANLIB, ranlib, /usr/bin/ranlib, /usr/bin:$PATH) 
  else
    AC_PROG_RANLIB
  fi
fi

AC_PROG_INSTALL

if test $GCC = "yes"; then
  gcc=$CC
else
  gcc=gcc
fi
AC_SUBST(gcc)

AC_CHECK_SIZEOF(short)
AC_CHECK_SIZEOF(int)
AC_CHECK_SIZEOF(long)
AC_CHECK_SIZEOF(long long)
AC_CHECK_SIZEOF(float)
AC_CHECK_SIZEOF(double)
AC_CHECK_SIZEOF(long double)

dnl look for cfitsio include and cfitsio library
dnl if installed in /usr/local, nothing to do

AC_MSG_CHECKING("for cfitsio lib")
MACHDIR=`uname`-$CXX
if test -f $ARCHBASEREP/$MACHDIR/Libs/libcfitsio.a; then
  cfitslibdir='-L$(ARCHBASEREP)/$(MACHDIR)/Libs'
elif test -f $EXTLIBDIR/$MACHDIR/Libs/libcfitsio.a; then
  cfitslibdir='-L$(EXTLIBDIR)/$(MACHDIR)/Libs'
elif test -f $CFITSIOLIBDIR/$MACHDIR/Libs/libcfitsio.a; then
  cfitslibdir='-L$(CFITSIOLIBDIR)/$(MACHDIR)/Libs'
elif test -f $CFITSIOLIBDIR/$MACHDIR/libcfitsio.a; then
  cfitslibdir='-L$(CFITSIOLIBDIR)/$(MACHDIR)'
elif test -f $CFITSIOLIBDIR/`uname`/lib/libcfitsio.a; then
  cfitslibdir='-L$(CFITSIOLIBDIR)/'`uname`/lib
elif test -f $CFITSIOLIBDIR/`uname`/libcfitsio.a; then
  cfitslibdir='-L$(CFITSIOLIBDIR)/'`uname`
elif test -f $CFITSIOLIBDIR/libcfitsio.a; then
  cfitslibdir='-L$(CFITSIOLIBDIR)'
elif test -f $CFITSIODIR/libcfitsio.a; then
  cfitslibdir='-L$(CFITSIODIR)'
elif test -f /usr/local/lib/libcfitsio.a; then
  cfitslibdir=""
else 
  AC_MSG_ERROR("Cannot find cfitsio library")
fi
AC_MSG_RESULT($cfitslibdir)
AC_SUBST(cfitslibdir)

AC_MSG_CHECKING("for cfitsio includes")
if test -f $CFITSIODIR/fitsio.h; then
  cfitsincdir='-I$(CFITSIODIR)'
elif test -f $EXTLIBDIR/Include/FitsIO/fitsio.h; then
  cfitsincdir='-I$(EXTLIBDIR)/Include/FitsIO'
elif test -f /usr/local/include/fitsio.h; then
  cfitsincdir=""
else
  AC_MSG_ERROR("Cannot find cfitsio include fitsio.h")
fi
AC_MSG_RESULT($cfitsincdir)
AC_SUBST(cfitsincdir)

dnl Checks for libraries.
dnl AC_CHECK_LIB(cfitsio, ffread,,AC_MSG_ERROR("Cannot find cfitsio library"))
AC_CHECK_LIB(m, sin)
AC_CHECK_LIB(pthread, pthread_create)
AC_CHECK_LIB(blas, scopy_)
AC_CHECK_LIB(g2c, s_copy)

dnl Check if piolib is available
if test $use_piolib = 1; then
  AC_MSG_CHECKING("for PIOLib")
  if test -f /usr/local/lib/libpiolib.a; then
    piolibdir=""
    pioincdir=""
  elif test -f $PIOLIBDIR/libpiolib.a; then
    piolibdir=$PIOLIBDIR
    pioincdir='-I$(PIOINCDIR)'
  else
    AC_MSG_ERROR("Cannot find PIO library")
  fi
  AC_MSG_RESULT("ok")
  AC_SUBST(piolibdir)
  AC_SUBST(pioincdir)
fi

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(values.h stdint.h)

outfiles="Makefile Kernel/Makefile Processors/Makefile TestPipes/Makefile"
if [[ $use_sophya = 1 ]]; then
  outfiles="$outfiles ProcWSophya/Makefile"
fi

AC_OUTPUT($outfiles)