#!/bin/csh 
# $Id: mkmflien,v 1.1.1.1 1999-11-26 16:37:08 ansari Exp $

#########################################################
#### repertoire contenant les repertoires du code+include
#########################################################
pushd ../.      > /dev/null
set src = ` pwd | sed 's?^/tmp_mnt??' `
popd            > /dev/null

#############################################################
#### repertoire contenant les liens a creer pour les includes
#############################################################
if( $#argv >= 1 ) then
  set dst = $1
else
  set dst = $DPCDEVREP/Include
endif
if ( ! -d $dst/ ) then
  echo repertoire $dst inconnu
  exit -1
endif

#########################################################
### Les includes a mettre dans Include pour les Makefiles
#########################################################
foreach f ( $src/Mgr/Makefile.h $src/Mgr/MakefileUser.h )
  if( -e $f ) then
    ln -sf $f $dst/
  endif
end

###################################################
####  Les includes de tnt a mettre dans Include/tnt
###################################################
if( -d $dst/tnt ) then
  if( -d $src/tnt ) then
    foreach f ( $src/tnt/*.h )
      ln -sf $f $dst/tnt/
    end
  endif
endif

###################################################
####  Les includes de Blitz++ lien ds Include
###################################################
if( -d $src/Blitz ) then
  ln -sf $src/Blitz/blitz $dst/blitz
endif

####################################################
####  Les includes du code C++ a mettre dans Include
####################################################
foreach d (`cat libdirs` PI PIext  )
  if ( -d $src/$d ) then
    echo $src/$d
    foreach f ( $src/$d/*.h )
      ln -sf $f $dst/
    end
  endif
end

exit 0