| 1 | #!/bin/csh
|
|---|
| 2 | # SOPHYA configuration managment script
|
|---|
| 3 | # C. Magneville / R. Ansari - Mai 2005
|
|---|
| 4 | # Updated : 2006, Avr/Mai , Oct 2007
|
|---|
| 5 | # Exemple: ./configure -sbase /laltmp/ansari/sbase/ -scxx cxx -extp /exp/planck/ExtLibs/Include/ \
|
|---|
| 6 | # -extp /exp/planck/ExtLibs/OSF1-cxx/
|
|---|
| 7 |
|
|---|
| 8 | #----------------------------------------------------------------------
|
|---|
| 9 | #### liste des modules
|
|---|
| 10 | set SOPMODOK = ( 1 1 1 1 1 1 1 1 1 )
|
|---|
| 11 | set SOPMOD = ( BaseTools SysTools SUtils TArray NTools HiStats SkyMap Samba SkyT )
|
|---|
| 12 | set ALLSOPLIBS = ( '-lBaseTools' '-lSysTools' '-lSUtils' '-lTArray' '-lNTools' '-lHiStats' '-lSkyMap' '-lSamba' '-lSkyT' )
|
|---|
| 13 |
|
|---|
| 14 | set SOPPIOK = ( 1 1 1 )
|
|---|
| 15 | set SOPPI = ( PI PIext PIGcont )
|
|---|
| 16 | set ALLPILIBS = ( '-lPI' '-lPIext' '-lPIGcont' )
|
|---|
| 17 |
|
|---|
| 18 | set SOPEXT = ( FitsIOServer IFFTW LinAlg XAstroPack )
|
|---|
| 19 | set EXTCURNAME = ( fits fftw lapack astro )
|
|---|
| 20 | set SOPEXTOK = ( 1 1 1 1 )
|
|---|
| 21 | set EXTINCNAME = ( FitsIO/fitsio.h FFTW/fftw3.h PASDEINC XAstro/astro.h )
|
|---|
| 22 | set EXTLIBNAME = ( libcfitsio.a libfftw3.a liblapack.a libxastro.a )
|
|---|
| 23 | set ALLEXTLIBS = ( '-lcfitsio' '-lfftw3' '-llapack -lblas' '-lxastro' )
|
|---|
| 24 |
|
|---|
| 25 | #FFTW2: set EXTINCNAME = ( FitsIO/fitsio.h FFTW/fftw.h PASDEINC XAstro/astro.h )
|
|---|
| 26 | #FFTW2: set EXTLIBNAME = ( libcfitsio.a libfftw.a liblapack.a libxastro.a )
|
|---|
| 27 | #FFTW2: set ALLEXTLIBS = ( '-lcfitsio' '-lfftw -lrfftw' '-llapack -lblas' '-lxastro' )
|
|---|
| 28 |
|
|---|
| 29 | set defextinc = ( /usr/include /usr/local/include )
|
|---|
| 30 | set defextlib = ( /usr/lib /usr/local/lib )
|
|---|
| 31 |
|
|---|
| 32 |
|
|---|
| 33 | #----------------------------------------------------------------------
|
|---|
| 34 | #### Decodage arguments
|
|---|
| 35 | set cmdline = "$0 $*"
|
|---|
| 36 | set extpath
|
|---|
| 37 | set extpathinc
|
|---|
| 38 | set extpathlib
|
|---|
| 39 | unset incln
|
|---|
| 40 | unset mincname
|
|---|
| 41 | set compopt
|
|---|
| 42 | unset arch64
|
|---|
| 43 | unset sasz64
|
|---|
| 44 | unset ssldble128
|
|---|
| 45 | unset nofpic
|
|---|
| 46 | unset nothsafe
|
|---|
| 47 | unset boundcheck
|
|---|
| 48 | unset sodebug
|
|---|
| 49 | unset usefftw2
|
|---|
| 50 | unset uselapack2
|
|---|
| 51 | unset alsofftwfloat
|
|---|
| 52 | unset slballinone
|
|---|
| 53 | while ( $#argv > 0 )
|
|---|
| 54 |
|
|---|
| 55 | if( "$1" == "-h" ) then
|
|---|
| 56 | echo 'configure [-sbase SOPHYABASE] [-scxx SOPHYACXX] [-incln] '
|
|---|
| 57 | echo " [-minc mymake.inc] [-compopt 'cc/cxxOptions'] "
|
|---|
| 58 | echo ' [-arch64] [-sasz64] [-ldble128] [-nofpic] [-nothsafe] [-boundcheck] [-sodebug]'
|
|---|
| 59 | echo ' [-extp dir1 -extp dir2 ...] [-extip dir1 -extip dir2 ... ] [-extlp dir1 -extlp dir2 ... ]'
|
|---|
| 60 | echo ' [-noextlib] [-noext fits] [-noext fftw] [-noext lapack] [-noext astro]'
|
|---|
| 61 | echo ' [-noPI] [-slballinone]'
|
|---|
| 62 | echo ' [-alsofftwfloat] [-usefftw2] [-uselapack2] '
|
|---|
| 63 | echo ' (See SOPHYA manual/web pages for a detailed description of configure options)'
|
|---|
| 64 | exit -1
|
|---|
| 65 | endif
|
|---|
| 66 | if( "$1" == "-sbase" ) then
|
|---|
| 67 | setenv SOPHYABASE $2
|
|---|
| 68 | shift
|
|---|
| 69 | endif
|
|---|
| 70 | if( "$1" == "-scxx" ) then
|
|---|
| 71 | setenv SOPHYACXX $2
|
|---|
| 72 | shift
|
|---|
| 73 | endif
|
|---|
| 74 | if( "$1" == "-incln" ) then
|
|---|
| 75 | set incln
|
|---|
| 76 | endif
|
|---|
| 77 | if( "$1" == "-minc" ) then
|
|---|
| 78 | set mincname = ( $2 )
|
|---|
| 79 | shift
|
|---|
| 80 | endif
|
|---|
| 81 | if( "$1" == "-compopt" ) then
|
|---|
| 82 | set compopt = ( $2 )
|
|---|
| 83 | shift
|
|---|
| 84 | endif
|
|---|
| 85 | if( "$1" == "-extp" ) then
|
|---|
| 86 | set extpath = ( $extpath $2 )
|
|---|
| 87 | shift
|
|---|
| 88 | endif
|
|---|
| 89 | if( "$1" == "-extip" ) then
|
|---|
| 90 | set extpathinc = ( $extpathinc $2 )
|
|---|
| 91 | shift
|
|---|
| 92 | endif
|
|---|
| 93 | if( "$1" == "-extlp" ) then
|
|---|
| 94 | set extpathlib = ( $extpathlib $2 )
|
|---|
| 95 | shift
|
|---|
| 96 | endif
|
|---|
| 97 | if( "$1" == "-noextlib" ) then
|
|---|
| 98 | set i = 0
|
|---|
| 99 | while ( $i < $#SOPEXTOK )
|
|---|
| 100 | @ i += 1
|
|---|
| 101 | set SOPEXTOK[$i] = 0
|
|---|
| 102 | end
|
|---|
| 103 | endif
|
|---|
| 104 | if( "$1" == "-noext" ) then
|
|---|
| 105 | set i = 0
|
|---|
| 106 | while ( $i < $#EXTCURNAME )
|
|---|
| 107 | @ i += 1
|
|---|
| 108 | if( "$2" == "$EXTCURNAME[$i]" ) set SOPEXTOK[$i] = 0
|
|---|
| 109 | end
|
|---|
| 110 | shift
|
|---|
| 111 | endif
|
|---|
| 112 | if( "$1" == "-PI" ) then
|
|---|
| 113 | set SOPPIOK = ( 0 0 0 )
|
|---|
| 114 | endif
|
|---|
| 115 | if( "$1" == "-alsofftwfloat" ) then
|
|---|
| 116 | # On veut la version float de FFTW, en plus de double
|
|---|
| 117 | set alsofftwfloat
|
|---|
| 118 | set i = 0
|
|---|
| 119 | while ( $i < $#EXTCURNAME )
|
|---|
| 120 | @ i += 1
|
|---|
| 121 | if( "fftw" == "$EXTCURNAME[$i]" ) then
|
|---|
| 122 | set ALLEXTLIBS[$i] = '-lfftw3 -lfftw3f'
|
|---|
| 123 | endif
|
|---|
| 124 | end
|
|---|
| 125 | endif
|
|---|
| 126 | if( "$1" == "-usefftw2" ) then
|
|---|
| 127 | # version FFTW 2 au lieu de V3
|
|---|
| 128 | set usefftw2
|
|---|
| 129 | set i = 0
|
|---|
| 130 | while ( $i < $#EXTCURNAME )
|
|---|
| 131 | @ i += 1
|
|---|
| 132 | if( "fftw" == "$EXTCURNAME[$i]" ) then
|
|---|
| 133 | set EXTINCNAME[$i] = 'FFTW/fftw.h'
|
|---|
| 134 | set EXTLIBNAME[$i] = 'libfftw.a'
|
|---|
| 135 | set ALLEXTLIBS[$i] = '-lfftw -lrfftw'
|
|---|
| 136 | endif
|
|---|
| 137 | end
|
|---|
| 138 | endif
|
|---|
| 139 | if( "$1" == "-uselapack2" ) then
|
|---|
| 140 | # version LAPACK 2 au lieu de V3
|
|---|
| 141 | set uselapack2
|
|---|
| 142 | endif
|
|---|
| 143 | if( "$1" == "-slballinone" ) then
|
|---|
| 144 | # Pour utiliser une seule librairie libsophyaPIext.so au lieu
|
|---|
| 145 | # des 3 libsophya.so libextsophya.so libPI.so
|
|---|
| 146 | set slballinone
|
|---|
| 147 | endif
|
|---|
| 148 | # Decodage options pour flags de machdefs.h
|
|---|
| 149 | # Liste de flags : SO_ARCH64 SO_NOFPIC SO_SASIZET64 SO_LDBLE128 SO_BOUNDCHECKING SOPHYA_DEBUG
|
|---|
| 150 | if( "$1" == "-arch64" ) then
|
|---|
| 151 | set arch64
|
|---|
| 152 | endif
|
|---|
| 153 | if( "$1" == "-sasz64" ) then
|
|---|
| 154 | set sasz64
|
|---|
| 155 | endif
|
|---|
| 156 | if( "$1" == "-ldble128" ) then
|
|---|
| 157 | set ssldble128
|
|---|
| 158 | endif
|
|---|
| 159 | if( "$1" == "-nofpic" ) then
|
|---|
| 160 | set nofpic
|
|---|
| 161 | endif
|
|---|
| 162 | if( "$1" == "-nothsafe" ) then
|
|---|
| 163 | set nothsafe
|
|---|
| 164 | endif
|
|---|
| 165 | if( "$1" == "-boundcheck" ) then
|
|---|
| 166 | set boundcheck
|
|---|
| 167 | endif
|
|---|
| 168 | if( "$1" == "-sodebug" ) then
|
|---|
| 169 | set sodebug
|
|---|
| 170 | endif
|
|---|
| 171 |
|
|---|
| 172 |
|
|---|
| 173 | shift
|
|---|
| 174 | end
|
|---|
| 175 |
|
|---|
| 176 | ## ------ Detection linux 64 bits ---
|
|---|
| 177 | unset linux64
|
|---|
| 178 | if ( `uname` == "Linux" ) then
|
|---|
| 179 | if ( `uname -m` == "x86_64" ) then
|
|---|
| 180 | echo ' ... Linux x86_64 (64 bits) ---> -arch64 '
|
|---|
| 181 | set linux64
|
|---|
| 182 | set arch64
|
|---|
| 183 | endif
|
|---|
| 184 | endif
|
|---|
| 185 |
|
|---|
| 186 |
|
|---|
| 187 | #----------------------------------------------------------------------
|
|---|
| 188 | #### Verification generale
|
|---|
| 189 | if( ! $?SOPHYABASE ) then
|
|---|
| 190 | echo ERROR: define SOPHYABASE or use script arguments
|
|---|
| 191 | exit -2
|
|---|
| 192 | endif
|
|---|
| 193 | if( ! $?SOPHYACXX ) then
|
|---|
| 194 | echo ERROR: define SOPHYACXX or use script arguments
|
|---|
| 195 | echo " SOPHYACXX define the name of the C++ compiler (ex: g++ cxx ...)"
|
|---|
| 196 | exit -2
|
|---|
| 197 | endif
|
|---|
| 198 | if( ! $?TMPDIR ) setenv TMPDIR /tmp
|
|---|
| 199 | touch $TMPDIR/tmp_test
|
|---|
| 200 | if( $status != 0 ) then
|
|---|
| 201 | echo ERROR: no write acces in temporary directory: $TMPDIR
|
|---|
| 202 | echo '----> define TMPDIR environment variable: "setenv TMPDIR ..."'
|
|---|
| 203 | exit -2
|
|---|
| 204 | endif
|
|---|
| 205 | rm -f $TMPDIR/tmp_test
|
|---|
| 206 | if( ! $?mincname ) then
|
|---|
| 207 | set mincname = `uname`_${SOPHYACXX}_make.inc
|
|---|
| 208 | endif
|
|---|
| 209 | if( ! -e $mincname ) then
|
|---|
| 210 | echo ERROR: file $mincname NOT found
|
|---|
| 211 | exit -2
|
|---|
| 212 | endif
|
|---|
| 213 | if( ! -e ../BaseTools/machdefs_mkmf.h ) then
|
|---|
| 214 | echo ERROR: file machdefs_mkmf.h NOT found in BaseTools
|
|---|
| 215 | exit -2
|
|---|
| 216 | endif
|
|---|
| 217 | echo SOPEXTOK: $SOPEXTOK
|
|---|
| 218 |
|
|---|
| 219 | #----------------------------------------------------------------------
|
|---|
| 220 | #### creation des variables chemins sophya core
|
|---|
| 221 | echo " "
|
|---|
| 222 | echo ">>>>>> 1/ Creating directory tree under $SOPHYABASE "
|
|---|
| 223 | set sinc = $SOPHYABASE/include
|
|---|
| 224 | set slib = $SOPHYABASE/lib
|
|---|
| 225 | set sslb = $SOPHYABASE/slb
|
|---|
| 226 | set sobj = $SOPHYABASE/obj
|
|---|
| 227 | set sexe = $SOPHYABASE/exe
|
|---|
| 228 | set sconf = $sinc/SophyaConfInfo
|
|---|
| 229 | foreach d ( $sinc $slib $sslb $sobj $sexe $sconf )
|
|---|
| 230 | if( ! -d $d ) then
|
|---|
| 231 | mkdir $d
|
|---|
| 232 | if( $status ) then
|
|---|
| 233 | echo ERROR: creation of $d failed
|
|---|
| 234 | exit -3
|
|---|
| 235 | endif
|
|---|
| 236 | echo Directory $d created
|
|---|
| 237 | endif
|
|---|
| 238 | touch $d/tmp_test
|
|---|
| 239 | if( $status ) then
|
|---|
| 240 | echo ERROR: no write acces to $d
|
|---|
| 241 | exit -4
|
|---|
| 242 | endif
|
|---|
| 243 | rm -f $d/tmp_test
|
|---|
| 244 | end
|
|---|
| 245 |
|
|---|
| 246 |
|
|---|
| 247 | #----------------------------------------------------------------------
|
|---|
| 248 | #### Fichier confinfo - log e configure
|
|---|
| 249 | set conflog = $sconf/conf.log
|
|---|
| 250 | rm -f $conflog ; touch $conflog
|
|---|
| 251 | echo ' --- Log of SOPHYA configure script - Date= ' `date` >> $conflog
|
|---|
| 252 | echo "$cmdline" >> $conflog
|
|---|
| 253 | set inclistf = $sconf/include.list
|
|---|
| 254 | rm -f $inclistf ; touch $inclistf
|
|---|
| 255 |
|
|---|
| 256 |
|
|---|
| 257 | #----------------------------------------------------------------------
|
|---|
| 258 | #### liens ou copie des *.h
|
|---|
| 259 | echo " "
|
|---|
| 260 | if( $?incln ) then
|
|---|
| 261 | echo ">>>>>> 2/ Creating symbolic link for include files in $sinc "
|
|---|
| 262 | else
|
|---|
| 263 | echo ">>>>>> 2/ Copying include files to $sinc "
|
|---|
| 264 | endif
|
|---|
| 265 |
|
|---|
| 266 | cd ../ > /dev/null
|
|---|
| 267 | set srcd = `pwd`
|
|---|
| 268 | set cpln = "cp -p "
|
|---|
| 269 | if( $?incln ) set cpln = "ln -s -f "
|
|---|
| 270 | foreach d ( $SOPMOD $SOPEXT $SOPPI )
|
|---|
| 271 | if ( -d $srcd/$d ) then
|
|---|
| 272 | if ( $?incln ) then
|
|---|
| 273 | echo Creating link to include files for module $d
|
|---|
| 274 | else
|
|---|
| 275 | echo Copying include files for module $d
|
|---|
| 276 | endif
|
|---|
| 277 |
|
|---|
| 278 | cd $srcd/$d;
|
|---|
| 279 | set file = ( *.h )
|
|---|
| 280 | cd $sinc; if( $status == 0 ) rm -f $file
|
|---|
| 281 | # on vire le .h de $file si .h dans excludeinc du module
|
|---|
| 282 | cd $srcd/$d
|
|---|
| 283 | if( -e excludeinc ) then
|
|---|
| 284 | if( `cat excludeinc | wc -l` > 0 ) then
|
|---|
| 285 | set file
|
|---|
| 286 | foreach f ( *.h )
|
|---|
| 287 | grep -q "$f:r\.h" excludeinc
|
|---|
| 288 | if( $status != 0 ) set file = ( $file $f )
|
|---|
| 289 | end
|
|---|
| 290 | endif
|
|---|
| 291 | endif
|
|---|
| 292 | # on copie ou link dans $sinc
|
|---|
| 293 | if( `echo $file | wc -w` > 0 ) then
|
|---|
| 294 | foreach f ( $file )
|
|---|
| 295 | $cpln $srcd/$d/$f $sinc/$f
|
|---|
| 296 | end
|
|---|
| 297 | endif
|
|---|
| 298 | echo $file >> $inclistf
|
|---|
| 299 | endif
|
|---|
| 300 | end
|
|---|
| 301 | rm -f $sinc/machdefs_ac.h $sinc/machdefs_mkmf.h
|
|---|
| 302 | cd $srcd/BuildMgr/.
|
|---|
| 303 |
|
|---|
| 304 |
|
|---|
| 305 | #----------------------------------------------------------------------
|
|---|
| 306 | #### lien des .h des librairies externes
|
|---|
| 307 | echo " "
|
|---|
| 308 | echo ">>>>>> 3/ Include files for external libraries "
|
|---|
| 309 | set i = 0
|
|---|
| 310 | while ( $i < $#SOPEXT )
|
|---|
| 311 | @ i += 1
|
|---|
| 312 | if( "$EXTINCNAME[$i]" == "PASDEINC" ) continue
|
|---|
| 313 | if( $SOPEXTOK[$i] <= 0 ) continue
|
|---|
| 314 | set nom = $EXTINCNAME[$i]:t
|
|---|
| 315 | set rac = $EXTINCNAME[$i]:h
|
|---|
| 316 | if( -d ../$SOPEXT[$i] ) then
|
|---|
| 317 | echo "Searching include file for $SOPEXT[$i] ..."
|
|---|
| 318 | foreach d ( $extpathinc $extpath $defextinc )
|
|---|
| 319 | set duminc = `find $d -name $nom -print -follow | head -1 `
|
|---|
| 320 | set dumrep = $duminc:h
|
|---|
| 321 | if ( "$dumrep" != "" ) then
|
|---|
| 322 | rm -f $sinc/$rac
|
|---|
| 323 | ln -f -s $dumrep $sinc/$rac
|
|---|
| 324 | echo Includes for $SOPEXT[$i] found in $dumrep
|
|---|
| 325 | break
|
|---|
| 326 | endif
|
|---|
| 327 | end
|
|---|
| 328 | if ( "$dumrep" == "" ) then
|
|---|
| 329 | echo WARNING: Includes for $SOPEXT[$i] NOT found
|
|---|
| 330 | echo " Compilation of module $SOPEXT[$i] disabled"
|
|---|
| 331 | set SOPEXTOK[$i] = 0
|
|---|
| 332 | endif
|
|---|
| 333 | endif
|
|---|
| 334 | end
|
|---|
| 335 |
|
|---|
| 336 |
|
|---|
| 337 | #----------------------------------------------------------------------
|
|---|
| 338 | #### liens des librairies externes
|
|---|
| 339 | echo " "
|
|---|
| 340 | echo ">>>>>> 4.1/ External libraries "
|
|---|
| 341 | set fpath = $TMPDIR/fpath
|
|---|
| 342 | rm -f $fpath; touch $fpath
|
|---|
| 343 | set extliblib
|
|---|
| 344 | set i = 0
|
|---|
| 345 | while ( $i < $#SOPEXT )
|
|---|
| 346 | @ i += 1
|
|---|
| 347 | if( "$EXTLIBNAME[$i]" == "PASDELIB" ) continue
|
|---|
| 348 | if( $SOPEXTOK[$i] <= 0 ) continue
|
|---|
| 349 | set nom = $EXTLIBNAME[$i]
|
|---|
| 350 | if( -d ../$SOPEXT[$i] ) then
|
|---|
| 351 | echo "Searching libraries path for $SOPEXT[$i] ..."
|
|---|
| 352 | foreach d ( $extpathlib $extpath $defextlib )
|
|---|
| 353 | set dumlib = `find $d -name $nom -print -follow | head -1 `
|
|---|
| 354 | if ( "$dumlib" != "" ) then
|
|---|
| 355 | echo "-L$dumlib:h" >> $fpath
|
|---|
| 356 | set extliblib = ( $extliblib $ALLEXTLIBS[$i] )
|
|---|
| 357 | break
|
|---|
| 358 | endif
|
|---|
| 359 | end
|
|---|
| 360 | if ( "$dumlib" == "" ) then
|
|---|
| 361 | echo WARNING: Libraries for $SOPEXT[$i] NOT found
|
|---|
| 362 | echo " Check the generated make.inc file"
|
|---|
| 363 | endif
|
|---|
| 364 | endif
|
|---|
| 365 | end
|
|---|
| 366 | set extlibpath = `cat $fpath | sort -u`
|
|---|
| 367 | echo extlibpath= $extlibpath
|
|---|
| 368 | echo extliblib= $extliblib
|
|---|
| 369 | rm -f $fpath
|
|---|
| 370 |
|
|---|
| 371 |
|
|---|
| 372 | #----------------------------------------------------------------------
|
|---|
| 373 | #### Identification des librairies archives Sophya
|
|---|
| 374 | echo " "
|
|---|
| 375 | echo ">>>>>> 4.2/ Sophya libraries archives "
|
|---|
| 376 | set sopmodlib
|
|---|
| 377 | set i = 0
|
|---|
| 378 | while ( $i < $#SOPMOD )
|
|---|
| 379 | @ i += 1
|
|---|
| 380 | if( $SOPMODOK[$i] <= 0 ) continue
|
|---|
| 381 | if( -d ../$SOPMOD[$i] ) then
|
|---|
| 382 | set sopmodlib = ( $sopmodlib $ALLSOPLIBS[$i] )
|
|---|
| 383 | else
|
|---|
| 384 | echo "WARNING: module "$SOPMOD[$i]" not found"
|
|---|
| 385 | endif
|
|---|
| 386 | end
|
|---|
| 387 | echo sopmodlib= $sopmodlib
|
|---|
| 388 |
|
|---|
| 389 | echo " "
|
|---|
| 390 | echo ">>>>>> 4.3/ PI-Sophya libraries archives "
|
|---|
| 391 | set soppilib
|
|---|
| 392 | set i = 0
|
|---|
| 393 | while ( $i < $#SOPPI )
|
|---|
| 394 | @ i += 1
|
|---|
| 395 | if( $SOPPIOK[$i] <= 0 ) continue
|
|---|
| 396 | if( -d ../$SOPPI[$i] ) then
|
|---|
| 397 | set soppilib = ( $soppilib $ALLPILIBS[$i] )
|
|---|
| 398 | else
|
|---|
| 399 | echo "WARNING: module "$SOPPI[$i]" not found"
|
|---|
| 400 | endif
|
|---|
| 401 | end
|
|---|
| 402 | echo soppilib= $soppilib
|
|---|
| 403 |
|
|---|
| 404 | #----------------------------------------------------------------------
|
|---|
| 405 | #### Generation de sophyamake.inc
|
|---|
| 406 | # On le cree dans le repertoire temporaire d'abord
|
|---|
| 407 | set mfile = $sinc/sophyamake.inc
|
|---|
| 408 | rm -f $mfile
|
|---|
| 409 | echo " "
|
|---|
| 410 | echo ">>>>>> 5/ Creating $mfile from $mincname "
|
|---|
| 411 | echo "# -----------------------------------------------" > $mfile
|
|---|
| 412 | echo "# File make.inc - generated by SOPHYA configure" >> $mfile
|
|---|
| 413 | echo "# Date" `date` >> $mfile
|
|---|
| 414 | echo "# Seed file : $mincname " >> $mfile
|
|---|
| 415 | echo "# -----------------------------------------------" >> $mfile
|
|---|
| 416 | echo " " >> $mfile
|
|---|
| 417 | echo "# SOPHYA Base installation directory " >> $mfile
|
|---|
| 418 | echo "SOPHYABASE = $SOPHYABASE" >> $mfile
|
|---|
| 419 | echo " " >> $mfile
|
|---|
| 420 | echo 'SOPHYAINCP = $(SOPHYABASE)/include/' >> $mfile
|
|---|
| 421 | echo 'SOPHYAOBJP = $(SOPHYABASE)/obj/' >> $mfile
|
|---|
| 422 | echo 'SOPHYALIBP = $(SOPHYABASE)/lib/' >> $mfile
|
|---|
| 423 | echo 'SOPHYASLBP = $(SOPHYABASE)/slb/' >> $mfile
|
|---|
| 424 | echo 'SOPHYAEXEP = $(SOPHYABASE)/exe/' >> $mfile
|
|---|
| 425 |
|
|---|
| 426 | echo " " >> $mfile
|
|---|
| 427 | echo "# module libraries " >> $mfile
|
|---|
| 428 | echo "SOPMODLIBLIST = $sopmodlib" >> $mfile
|
|---|
| 429 |
|
|---|
| 430 | echo " " >> $mfile
|
|---|
| 431 | echo "# External libraries PATH " >> $mfile
|
|---|
| 432 | echo "SOPEXTLIBP = $extlibpath" >> $mfile
|
|---|
| 433 | echo "SOPEXTLIBLIST = $extliblib" >> $mfile
|
|---|
| 434 |
|
|---|
| 435 | echo " " >> $mfile
|
|---|
| 436 | echo "# PI libraries " >> $mfile
|
|---|
| 437 | echo "SOPPILIBLIST = $soppilib" >> $mfile
|
|---|
| 438 |
|
|---|
| 439 | echo " " >> $mfile
|
|---|
| 440 | cat $mincname >> $mfile
|
|---|
| 441 |
|
|---|
| 442 | # --- Gestion des flags modifiants les options de compilation et liste de librairies (par sed)
|
|---|
| 443 | set sname = `uname`
|
|---|
| 444 | set sprgfile = $TMPDIR/compop.scom
|
|---|
| 445 | rm -f $sprgfile
|
|---|
| 446 | echo '{' > $sprgfile
|
|---|
| 447 | set scmd = "/FLAGS/s/CNFPHFLF/ $compopt/g"
|
|---|
| 448 | if ( $?arch64 ) then
|
|---|
| 449 | set a64cf = ' '
|
|---|
| 450 | if ( ( "$sname" == "IRIX64" ) && ("$SOPHYACXX" == "CC" ) ) set a64cf = '-64'
|
|---|
| 451 | if ( "$sname" == "AIX" ) then
|
|---|
| 452 | if ( ("$SOPHYACXX" == "xlC" ) || ("$SOPHYACXX" == "xlc" ) ) set a64cf = '-q64'
|
|---|
| 453 | echo "/ARFLAGS/s/-rcs/-rcs -X 64/" >> $sprgfile
|
|---|
| 454 | endif
|
|---|
| 455 | set scmd = "/FLAGS/s/CNFPHFLF/$a64cf $compopt/g"
|
|---|
| 456 | endif
|
|---|
| 457 | echo $scmd >> $sprgfile
|
|---|
| 458 | if ( $?nofpic ) echo "s/-fPIC/ /g" >> $sprgfile
|
|---|
| 459 | if( $?slballinone ) then
|
|---|
| 460 | echo "/SOPHYAALLSLBLIST/s/-lPI -lextsophya -lsophya/-lAsophyaextPI/" >> $sprgfile
|
|---|
| 461 | echo "/SOPHYAEXTSLBLIST/s/-lextsophya -lsophya/-lAsophyaextPI/" >> $sprgfile
|
|---|
| 462 | endif
|
|---|
| 463 | if ( $?linux64 ) then
|
|---|
| 464 | echo "s?-L/usr/X11R6/lib?-L/usr/X11R6/lib64?g" >> $sprgfile
|
|---|
| 465 | endif
|
|---|
| 466 | echo '}' >> $sprgfile
|
|---|
| 467 | set mftmp = $TMPDIR/sopmake.inc
|
|---|
| 468 | cp $mfile $mftmp
|
|---|
| 469 | rm -f $mfile
|
|---|
| 470 | sed -f $sprgfile $mftmp > $mfile
|
|---|
| 471 | rm -f $sprgfile $mftmp
|
|---|
| 472 | # --- FIN de gestion des flags modifiants les options de compilation (par sed)
|
|---|
| 473 |
|
|---|
| 474 | rm -f $mfile:t
|
|---|
| 475 | ln -s $mfile $mfile:t
|
|---|
| 476 |
|
|---|
| 477 |
|
|---|
| 478 | #----------------------------------------------------------------------
|
|---|
| 479 | #### Copie de machdefs.h
|
|---|
| 480 | set mdefname = $TMPDIR/machdefs.h
|
|---|
| 481 | echo " "
|
|---|
| 482 | echo ">>>>>> 6.a/ Creating machdefs.h from BaseTools/machdefs_mkmf.h"
|
|---|
| 483 | rm -f $mdefname; touch $mdefname
|
|---|
| 484 | echo "/*** machdefs.h generated by SOPHYA configure ***/" >> $mdefname
|
|---|
| 485 | echo "#ifndef MACHDEFS_SEEN" >> $mdefname
|
|---|
| 486 | echo "#define MACHDEFS_SEEN" >> $mdefname
|
|---|
| 487 | echo "/*------ Code generation switch ---- */" >> $mdefname
|
|---|
| 488 | echo "/* System selector (uname) */" >> $mdefname
|
|---|
| 489 | # Fait avant - set sname = `uname`
|
|---|
| 490 | echo "#ifndef $sname" >> $mdefname
|
|---|
| 491 | echo "#define $sname 1 " >> $mdefname
|
|---|
| 492 | echo "#endif" >> $mdefname
|
|---|
| 493 |
|
|---|
| 494 | ## Definition de flags de compilation en fonction des options de configure
|
|---|
| 495 | if ( $?arch64 ) echo "#define SO_ARCH64 1" >> $mdefname
|
|---|
| 496 | if ( $?sasz64 ) echo "#define SO_SASIZET64 1" >> $mdefname
|
|---|
| 497 | if ( $?ssldble128 ) echo "#define SO_LDBLE128 1" >> $mdefname
|
|---|
| 498 | if ( $?nofpic ) echo "#define SO_NOFPIC 1" >> $mdefname
|
|---|
| 499 | if ( $?nothsafe ) echo "#define SO_NOTHSAFE 1" >> $mdefname
|
|---|
| 500 | if ( $?boundcheck ) echo "#define SO_BOUNDCHECKING 1" >> $mdefname
|
|---|
| 501 | if ( $?sodebug ) echo "#define SOPHYA_DEBUG 1" >> $mdefname
|
|---|
| 502 |
|
|---|
| 503 | if ( "$sname" == "IRIX64" ) then
|
|---|
| 504 | if ( "$SOPHYACXX" == "CC" ) then
|
|---|
| 505 | # __SGICC__ : flag indiquant que c'est le compilo CC de SGI
|
|---|
| 506 | echo "#define __SGICC__ 1" >> $mdefname
|
|---|
| 507 | endif
|
|---|
| 508 | endif
|
|---|
| 509 |
|
|---|
| 510 |
|
|---|
| 511 | echo " " >> $mdefname
|
|---|
| 512 | grep -v -e '#ifndef *MACHDEFS_SEEN' -e '#define *MACHDEFS_SEEN' ../BaseTools/machdefs_mkmf.h >> $mdefname
|
|---|
| 513 | # On ne copie que si machdefs.h est different
|
|---|
| 514 | if (-e $sinc/machdefs.h ) then
|
|---|
| 515 | diff $mdefname $sinc/machdefs.h >& /dev/null
|
|---|
| 516 | if ($status != 0) then
|
|---|
| 517 | cp -f -p $mdefname $sinc/machdefs.h
|
|---|
| 518 | echo " file $sinc/machdefs.h changed -> replaced"
|
|---|
| 519 | else
|
|---|
| 520 | echo " file $sinc/machdefs.h has not changed -> kept"
|
|---|
| 521 | endif
|
|---|
| 522 | else
|
|---|
| 523 | cp -f -p $mdefname $sinc/machdefs.h
|
|---|
| 524 | echo " file $sinc/machdefs.h created"
|
|---|
| 525 | endif
|
|---|
| 526 | rm -f $mdefname
|
|---|
| 527 |
|
|---|
| 528 |
|
|---|
| 529 | #### Creation de sspvflags.h
|
|---|
| 530 | echo " "
|
|---|
| 531 | echo ">>>>>> 6.b/ Creating $sinc/sspvflags.h "
|
|---|
| 532 | rm -f $sinc/sspvflags.h; touch $sinc/sspvflags.h
|
|---|
| 533 |
|
|---|
| 534 | echo "#ifndef SSPVFLAGS_SEEN" >> $sinc/sspvflags.h
|
|---|
| 535 | echo "#define SSPVFLAGS_SEEN" >> $sinc/sspvflags.h
|
|---|
| 536 | echo " " >> $sinc/sspvflags.h
|
|---|
| 537 | echo "/*------ External libraries no-use flag ---- */" >> $sinc/sspvflags.h
|
|---|
| 538 | set i = 0
|
|---|
| 539 | while ( $i < $#SOPEXTOK )
|
|---|
| 540 | @ i += 1
|
|---|
| 541 | if( $SOPEXTOK[$i] > 0 ) continue
|
|---|
| 542 | echo "#define SOPHYA_NO_$SOPEXT[$i]" >> $sinc/sspvflags.h
|
|---|
| 543 | end
|
|---|
| 544 |
|
|---|
| 545 | echo " " >> $sinc/sspvflags.h
|
|---|
| 546 | echo "/*------ SOPOHYA/ExtLibsvVersion selection flags ---- */" >> $sinc/sspvflags.h
|
|---|
| 547 | echo " " >> $sinc/sspvflags.h
|
|---|
| 548 | if( $?alsofftwfloat ) then
|
|---|
| 549 | echo "/*-- Compile ALSO float version of FFTWServer methods -- */" >> $sinc/sspvflags.h
|
|---|
| 550 | echo "#define ALSO_FFTW_FLOAT_EXTSOP" >> $sinc/sspvflags.h
|
|---|
| 551 | endif
|
|---|
| 552 | if( $?usefftw2 ) then
|
|---|
| 553 | echo "/*-- Use FFTW V2 instead of V3 -- */" >> $sinc/sspvflags.h
|
|---|
| 554 | echo "#define FFTW_V2_EXTSOP" >> $sinc/sspvflags.h
|
|---|
| 555 | endif
|
|---|
| 556 | if( $?uselapack2 ) then
|
|---|
| 557 | echo "/*-- Use LAPACK V2 instead of V3 -- */" >> $sinc/sspvflags.h
|
|---|
| 558 | echo "#define LAPACK_V2_EXTSOP" >> $sinc/sspvflags.h
|
|---|
| 559 | endif
|
|---|
| 560 | echo " " >> $sinc/sspvflags.h
|
|---|
| 561 | if( $?slballinone ) then
|
|---|
| 562 | echo "/*------ Use of single shared lib for SOPHYA+extlibs+PI ---- */" >> $sinc/sspvflags.h
|
|---|
| 563 | echo "#define SO_SLBALLINONE " >> $sinc/sspvflags.h
|
|---|
| 564 | endif
|
|---|
| 565 | echo " " >> $sinc/sspvflags.h
|
|---|
| 566 | echo "#endif " >> $sinc/sspvflags.h
|
|---|
| 567 |
|
|---|
| 568 |
|
|---|
| 569 | #----------------------------------------------------------------------
|
|---|
| 570 | #### Creation des fichiers contenant les listes d'objets et d'includes
|
|---|
| 571 | echo " "
|
|---|
| 572 | echo ">>>>>> 7/ Creating object list files for shared library creation "
|
|---|
| 573 | set objlistname = $sconf/libsophya.objlist
|
|---|
| 574 | echo " 7.a/ Creating $objlistname "
|
|---|
| 575 | rm -f $objlistname ; touch $objlistname
|
|---|
| 576 | foreach d ( $SOPMOD )
|
|---|
| 577 | rm -f $sconf/$d.conf
|
|---|
| 578 | if ( ! -d ../$d ) continue
|
|---|
| 579 | cat ../$d/objlist.list >> $objlistname
|
|---|
| 580 | touch $sconf/$d.conf
|
|---|
| 581 | end
|
|---|
| 582 |
|
|---|
| 583 | set objlistname = $sconf/libextsophya.objlist
|
|---|
| 584 | echo " 7.b/ Creating $objlistname "
|
|---|
| 585 | rm -f $objlistname ; touch $objlistname
|
|---|
| 586 | set i = 0
|
|---|
| 587 | while ( $i < $#SOPEXT )
|
|---|
| 588 | @ i += 1
|
|---|
| 589 | set d = $SOPEXT[$i]
|
|---|
| 590 | rm -f $sconf/$d.conf
|
|---|
| 591 | if( $SOPEXTOK[$i] <= 0 ) continue
|
|---|
| 592 | if ( ! -d ../$d ) continue
|
|---|
| 593 | cat ../$d/objlist.list >> $objlistname
|
|---|
| 594 | touch $sconf/$d.conf
|
|---|
| 595 | end
|
|---|
| 596 |
|
|---|
| 597 | set objlistname = $sconf/libPI.objlist
|
|---|
| 598 | echo " 7.c/ Creating $objlistname "
|
|---|
| 599 | rm -f $objlistname ; touch $objlistname
|
|---|
| 600 | set i = 0
|
|---|
| 601 | while ( $i < $#SOPPI )
|
|---|
| 602 | @ i += 1
|
|---|
| 603 | set d = $SOPPI[$i]
|
|---|
| 604 | rm -f $sconf/$d.conf
|
|---|
| 605 | if( $SOPPIOK[$i] <= 0 ) continue
|
|---|
| 606 | if ( ! -d ../$d ) continue
|
|---|
| 607 | cat ../$d/objlist.list >> $objlistname
|
|---|
| 608 | touch $sconf/$d.conf
|
|---|
| 609 | end
|
|---|
| 610 |
|
|---|
| 611 |
|
|---|
| 612 | #----------------------------------------------------------------------
|
|---|
| 613 | exit 0
|
|---|
![(please configure the [header_logo] section in trac.ini)](/PI/chrome/site/your_project_logo.png){kind=logo}
