source: PSPA/madxPSPA/tests/share/LEIR/LEIR.seqx

Last change on this file was 430, checked in by touze, 11 years ago

import madx-5.01.00
File size: 16.0 KB
Line 
1! LEIR Lattice definitions
2
3! Input parameter to be provided before calling :
4
5!  LSSH  .... half length of straight section from "mire to mire"
6
7!  dLSext ... Quad length reduction due to a Sextupole close to it
8!  dLBmp  ... Quad length reduction due to a Bumper close to it
9!  dLDip  ... Quad length reduction due to a Dipole close to it
10!  dLSol  ... Quad length reduction due to a Correction solenoid close
11!  dLSkew ... Quad length reduction due to a Skew Quad close to it
12!  KickEC ... Flag (multiplier) wheter if kicks due to toroid should be taken into account (=1)
13
14  TuneH  =  1.82;
15  TuneV  =  2.72;
16  DisEC  = -0.00;
17  BetHEC =  5.00;
18  BetVEC =  5.00;
19  kEddy  =  0.00;
20
21 ! Define lattice .... first parameter, then CALL a routine
22
23 ! LSSH = ((25.-2*4.17)*Pi - .0052)/8. ! To have a circumf. of 25 Pi m
24  LSSH = 6.5422;                        ! From fit to survey data
25  DFD = 0.;  !  Flag, if 1 DFD, if 0 FDF
26  dLSext = 0.005;  ! Mag. length decrease of Quads due to adjacent X-Pole
27  dLBmp  = 0.000;  ! Mag. length decrease of Quads due to adjacent Bumper
28  dLDip  = 0.000;  ! Mag. length decrease of Quads due to adjacent Dipole
29  dLSol  = 0.000;  ! Mag. length decrease of Quads due to adjacent correct. Sol.
30  dLSkew = 0.005;  ! Mag. length decrease of Quads due to adjacent Skew Quad
31  KickEC = 1.;     ! Flag whether kick due to cooler is taken into account (=1) or not (-0)   
32
33
34  kD1030   =-1.1303*(1-DFD) - 1.2003*DFD;
35  kF1030   = 0.9041*(1-DFD) + 0.9286*DFD;
36  kF2040   = .30876*(1-DFD) - 1.2094*DFD;
37  kD2040   =-1.3181*(1-DFD) + 0.9226*DFD;
38  kF2344   = 0.7167*(1-DFD) - 0.0918*DFD;
39  dkFT20   = 0.0;
40  dkDT20   = 0.0;
41  dkFT23   = 0.0;  ! strictly applies for ER.QFN24 and ER.QFN23
42  Msol     = 0.0;
43  MsolC    = 0.0;
44  kSk1     = 0.0;
45  kEddy    = 0.0;
46
47  LFrMir =  1.11684*((1 - cos(0.240964) + sin(0.240964))/0.240964) +       
48            0.01575*(sin(0.240964) + cos(0.240964)) +                     
49            2.13554*((cos(0.240964) - Sin(0.240964))/(Pi/4. - 0.240964)) +
50            0.07299*sqrt(2.) - 4.17;
51  LstrH = LSSH - LFrMir;
52  LbenH = 1.11684 + 0.01575 + 2.13554 + 0.07299;
53
54! RF system (my test) ... for CHARGE=1 ... VOLTAGE should be scale --> devided by 54
55! Vrf=2.2kV / H=2 / Fsynch = 1.567kHz
56  CAV: RFCAVITY, L=1.0, VOLT=0.0022/54, HARMON=2, LAG=0, no_cavity_totalpath; 
57
58
59! Definitions for bending blocks
60  ED1 =-0.01157;
61  ED2 = 0.01500;
62  ED3 = 0.09557;
63  BA1HO :  SBEND, L=1.11684/2.,            ANGLE=-0.240964/2.,                                  K1:=kEddy, K2:=sEddy, E1=-ED1, E2= 0   ;
64  BA1HI :  SBEND, L=1.11684/2.,            ANGLE=-0.240964/2.,                                  K1:=kEddy, K2:=sEddy, E1= 0,   E2=-ED2 ;
65  BI1PO :  SBEND, L=2.13554-0.2620-1.4778, ANGLE=-(Pi/4.-0.240964)*(1-(1.4778+0.2620)/2.13554), K1:=kEddy, K2:=sEddy, E1= 0,   E2= 0   ;
66  BI1PM :  SBEND, L=0.2620,                ANGLE=-(Pi/4.-0.240964)*0.2620/2.13554,              K1:=kEddy, K2:=sEddy, E1= 0,   E2= 0   ;
67  BI1PI :  SBEND, L=1.4778,                ANGLE=-(Pi/4.-0.240964)*1.4778/2.13554,              K1:=kEddy, K2:=sEddy, E1= 0,   E2=-ED3 ;
68  BI2PI :  SBEND, L=1.4778,                ANGLE=-(Pi/4.-0.240964)*1.4778/2.13554,              K1:=kEddy, K2:=sEddy, E1=-ED3, E2= 0   ;
69  BI2PM :  SBEND, L=0.2620,                ANGLE=-(Pi/4.-0.240964)*0.2620/2.13554,              K1:=kEddy, K2:=sEddy, E1= 0,   E2= 0   ;
70  BI2PO :  SBEND, L=2.13554-0.2620-1.4778, ANGLE=-(Pi/4.-0.240964)*(1-(1.4778+0.2620)/2.13554), K1:=kEddy, K2:=sEddy, E1= 0,   E2= 0   ;
71  BA2HI :  SBEND, L=1.11684/2.,            ANGLE=-0.240964/2.,                                  K1:=kEddy, K2:=sEddy, E1=-ED2, E2= 0   ;
72  BA2HO :  SBEND, L=1.11684/2.,            ANGLE=-0.240964/2.,                                  K1:=kEddy, K2:=sEddy, E1= 0,   E2=-ED1 ;
73  DBA   :  DRIFT, L=0.01575;
74  DBI   :  DRIFT, L=0.07299;
75
76! Quadrupole families
77  QDN1030 : QUADRUPOLE, L=0.5172, K1 := kD1030;
78  QFN1030 : QUADRUPOLE, L=0.5172, K1 := kF1030;
79
80  QFN2040 : QUADRUPOLE, L=0.5172, K1 := kF2040;
81  QDN2040 : QUADRUPOLE, L=0.5172, K1 := kD2040;
82  QFN2344 : QUADRUPOLE, L=0.5172, K1 := kF2344;
83
84  QFT20   : QUADRUPOLE, L=0.5172, K1 := kF2040 + dkFT20;
85  QDT20   : QUADRUPOLE, L=0.5172, K1 := kD2040 + dkDT20;
86  QFT23   : QUADRUPOLE, L=0.5172, K1 := kF2344 + dkFT23;
87  QFT24   : QUADRUPOLE, L=0.5172, K1 := kF2344 + dkFT23;
88
89! Sextupoles
90  XFW01   : MULTIPOLE, KNL := {0, 0, 1.11684*sW01}; 
91  XFW02   : MULTIPOLE, KNL := {0, 0, 1.11684*sW02}; 
92
93  XDN11   : SEXTUPOLE, L=0.33535, K2 := sD1030;
94  XFN11   : SEXTUPOLE, L=0.33535, K2 := sF1030;
95  XFN12   : SEXTUPOLE, L=0.33535, K2 := sF1030;
96  XDN12   : SEXTUPOLE, L=0.33535, K2 := sD1030;
97
98  XDN31   : SEXTUPOLE, L=0.33535, K2 := sD1030;
99  XFN31   : SEXTUPOLE, L=0.33535, K2 := sF1030;
100  XFN32   : SEXTUPOLE, L=0.33535, K2 := sF1030;
101  XDN32   : SEXTUPOLE, L=0.33535, K2 := sD1030;
102
103  XFLS41 : SEXTUPOLE, L=0.33535, K2 := sF40; 
104  XFLS42 : SEXTUPOLE, L=0.33535, K2 := sF40; 
105
106! Dipoles, Bumpers and (extraction) Kicker :
107  DWHV11 : KICKER;
108  DFH11  : HKICKER, KICK := dBmpI;
109  DHV12  : KICKER;
110  DFH12  : HKICKER, KICK := dBmpI;
111  DWHV12 : KICKER;
112
113  DWHV21 : KICKER;
114  DFH21  : HKICKER, KICK := dBmpO;
115  DEHV21 : KICKER;
116  DEHV22 : KICKER;
117  DWHV22 : KICKER;
118
119  DWHV31 : KICKER;
120  KFH31  : HKICKER;  ! "extraction" kicker
121  DHV31  : KICKER;
122  KFH3234: HKICKER;  ! extraction kicker
123  DWHV32 : KICKER;
124
125  DHV41  : KICKER;
126  DHV42  : KICKER;
127  DFH42  : HKICKER, KICK := dBmpO;
128  DWHV41 : KICKER;
129  DWHV42 : KICKER;
130
131! Pick-ups all defined in "SEQUENCE" command
132
133! Solenoid and compensation Elements (Skew-Quads + Solenoids)
134!  Modeling of Cooler + Compensators provided by J. Pasternak
135  EC0    : SOLENOID,   L=0.18787, KS := 0.1059*Msol;
136  ECDH1  : HKICKER,    KICK :=  KickEC*0.022919*Msol*1.138/0.0756;
137  EC1    : SOLENOID,   L=0.48451, KS := 0.549*Msol;
138  ECQSI1 : MULTIPOLE,             KSL:={0, -(1/59.5808)*Msol*1.138/0.0756};
139  EC2    : SOLENOID,   L=0.15578, KS := 0.74*Msol;
140  ECQSI2 : MULTIPOLE,             KSL:={0, -(1/55.8782)*Msol*1.138/0.0756};
141  EC3    : SOLENOID,   L=0.53184, KS := 0.9*Msol;
142  EC4    : SOLENOID,   L=0.110,   KS := 1.02*Msol;
143  EC5H   : SOLENOID,   L=1.089,   KS := Msol;
144  ECQS01 : MULTIPOLE,             KSL:={0, (1/59.5808)*Msol*1.138/0.0756};
145  ECQS02 : MULTIPOLE,             KSL:={0, (1/55.8782)*Msol*1.138/0.0756};
146  ECDH2  : HKICKER,    KICK := -KickEC*0.022919*Msol*1.138/0.0756;
147
148  QSK21  : QUADRUPOLE, L=0.32,   K1S := kSk1;
149  SOL21  : SOLENOID,   L=0.427,  KS  := MsolC;
150  SOL22  : SOLENOID,   L=0.427,  KS  := MsolC;
151  QSK22  : QUADRUPOLE, L=0.32,   K1S :=-kSk1;
152
153! RF cavities
154!  CRF41  : MARKER;
155  CRF43  : MARKER;
156
157! Special Diagnostics
158  MPIV42 : MONITOR;
159  MSH42  : MONITOR;
160  MSV42  : MONITOR;
161
162! Put pieces together to form Arcs
163  Arc10  : SEQUENCE, l=2*LbenH;
164    BA1HO.1 : BA1HO,    AT=1.11684/4.;
165    DWHV11,             AT=1.11684/2.;
166    XFW11   : XFW01,    AT=1.11684/2.;
167    BA1HI.1 : BA1HI,    AT=1.11684*(3./4.);
168    BI1PO.1 : BI1PO,    AT=LbenH - (0.07299 + 1.4778 + 0.2620 + (2.13554-0.2620-1.4778)/2);
169    UEV13   : VMONITOR, AT=LbenH - (0.07299 + 1.4778 + 0.2620);
170    BI1PM.1 : BI1PM,    AT=LbenH - (0.07299 + 1.4778 + 0.2620/2);
171    UEH13   : HMONITOR, AT=LbenH - (0.07299 + 1.4778);
172    BI1PI.1 : BI1PI,    AT=LbenH - (0.07299 + 1.4778/2);
173    CtrBHN10: MARKER,   AT=LbenH;
174    BI2PI.1 : BI2PI,    AT=LbenH + (0.07299 + 1.4778/2);
175    UEH14   : HMONITOR, AT=LbenH + (0.07299 + 1.4778);
176    BI2PM.1 : BI2PM,    AT=LbenH + (0.07299 + 1.4778 + 0.2620/2);
177    UEV14   : VMONITOR, AT=LbenH + (0.07299 + 1.4778 + 0.2620);
178    BI2PO.1 : BI2PO,    AT=LbenH + (0.07299 + 1.4778 + 0.2620 + (2.13554-0.2620-1.4778)/2);
179    BA2HI.1 : BA2HI,    AT=2*LbenH - 1.11684*(3./4.);
180    XFW12   : XFW02,    AT=2*LbenH - 1.11684/2.;
181    DWHV12,             AT=2*LbenH - 1.11684/2.;
182    BA2HO.1 : BA2HO,    AT=2*LbenH - 1.11684/4.;
183  ENDSEQUENCE;
184  Arc20  : SEQUENCE, l=2*LbenH;
185    BA1HO.2 : BA1HO,    AT=1.11684/4.;
186    DWHV21,             AT=1.11684/2.;
187    XFW21   : XFW02,    AT=1.11684/2.;
188    BA1HI.2 : BA1HI,    AT=1.11684*(3./4.);
189    BI1PO.2 : BI1PO,    AT=LbenH - (0.07299 + 1.4778 + 0.2620 + (2.13554-0.2620-1.4778)/2);
190    UEV23   : VMONITOR, AT=LbenH - (0.07299 + 1.4778 + 0.2620);
191    BI1PM.2 : BI1PM,    AT=LbenH - (0.07299 + 1.4778 + 0.2620/2);
192    UEH23   : HMONITOR, AT=LbenH - (0.07299 + 1.4778);
193    BI1PI.2 : BI1PI,    AT=LbenH - (0.07299 + 1.4778/2);
194    CtrBHN20: MARKER,   AT=LbenH;
195    BI2PI.2 : BI2PI,    AT=LbenH + (0.07299 + 1.4778/2);
196    UEH24   : HMONITOR, AT=LbenH + (0.07299 + 1.4778);
197    BI2PM.2 : BI2PM,    AT=LbenH + (0.07299 + 1.4778 + 0.2620/2);
198    UEV24   : VMONITOR, AT=LbenH + (0.07299 + 1.4778 + 0.2620);
199    BI2PO.2 : BI2PO,    AT=LbenH + (0.07299 + 1.4778 + 0.2620 + (2.13554-0.2620-1.4778)/2);
200    BA2HI.2 : BA2HI,    AT=2*LbenH - 1.11684*(3./4.);
201    XFW22   : XFW01,    AT=2*LbenH - 1.11684/2.;
202    DWHV22,             AT=2*LbenH - 1.11684/2.;
203    BA2HO.2 : BA2HO,    AT=2*LbenH - 1.11684/4.;
204  ENDSEQUENCE;
205  Arc30  : SEQUENCE, l=2*LbenH;
206    BA1HO.3 : BA1HO,    AT=1.11684/4.;
207    DWHV31,             AT=1.11684/2.;
208    XFW31   : XFW01,    AT=1.11684/2.;
209    BA1HI.3 : BA1HI,    AT=1.11684*(3./4.);
210    BI1PO.3 : BI1PO,    AT=LbenH - (0.07299 + 1.4778 + 0.2620 + (2.13554-0.2620-1.4778)/2);
211    UEV33   : VMONITOR, AT=LbenH - (0.07299 + 1.4778 + 0.2620);
212    BI1PM.3 : BI1PM,    AT=LbenH - (0.07299 + 1.4778 + 0.2620/2);
213    UEH33   : HMONITOR, AT=LbenH - (0.07299 + 1.4778);
214    BI1PI.3 : BI1PI,    AT=LbenH - (0.07299 + 1.4778/2);
215    CtrBHN30: MARKER,   AT=LbenH;
216    BI2PI.3 : BI2PI,    AT=LbenH + (0.07299 + 1.4778/2);
217    UEH34   : HMONITOR, AT=LbenH + (0.07299 + 1.4778);
218    BI2PM.3 : BI2PM,    AT=LbenH + (0.07299 + 1.4778 + 0.2620/2);
219    UEV34   : VMONITOR, AT=LbenH + (0.07299 + 1.4778 + 0.2620);
220    BI2PO.3 : BI2PO,    AT=LbenH + (0.07299 + 1.4778 + 0.2620 + (2.13554-0.2620-1.4778)/2);
221    BA2HI.3 : BA2HI,    AT=2*LbenH - 1.11684*(3./4.);
222    XFW32   : XFW02,    AT=2*LbenH - 1.11684/2.;
223    DWHV32,             AT=2*LbenH - 1.11684/2.;
224    BA2HO.3 : BA2HO,    AT=2*LbenH - 1.11684/4.;
225  ENDSEQUENCE;
226  Arc40  : SEQUENCE, l=2*LbenH;
227    BA1HO.4 : BA1HO,    AT=1.11684/4.;
228    DWHV41,             AT=1.11684/2.;
229    XFW41,  : XFW02,    AT=1.11684/2.;
230    BA1HI.4 : BA1HI,    AT=1.11684*(3./4.);
231    BI1PO.4 : BI1PO,    AT=LbenH - (0.07299 + 1.4778 + 0.2620 + (2.13554-0.2620-1.4778)/2);
232    UEV43   : VMONITOR, AT=LbenH - (0.07299 + 1.4778 + 0.2620);
233    BI1PM.4 : BI1PM,    AT=LbenH - (0.07299 + 1.4778 + 0.2620/2);
234    UEH43   : HMONITOR, AT=LbenH - (0.07299 + 1.4778);
235    BI1PI.4 : BI1PI,    AT=LbenH - (0.07299 + 1.4778/2);
236    CtrBHN40: MARKER,   AT=LbenH;
237    BI2PI.4 : BI2PI,    AT=LbenH + (0.07299 + 1.4778/2);
238    UEH44   : HMONITOR, AT=LbenH + (0.07299 + 1.4778);
239    BI2PM.4 : BI2PM,    AT=LbenH + (0.07299 + 1.4778 + 0.2620/2);
240    UEV44   : VMONITOR, AT=LbenH + (0.07299 + 1.4778 + 0.2620);
241    BI2PO.4 : BI2PO,    AT=LbenH + (0.07299 + 1.4778 + 0.2620 + (2.13554-0.2620-1.4778)/2);
242    BA2HI.4 : BA2HI,    AT=2*LbenH - 1.11684*(3./4.);
243    XFW42   : XFW01,    AT=2*LbenH - 1.11684/2.;
244    DWHV42,             AT=2*LbenH - 1.11684/2.;
245    BA2HO.4 : BA2HO,    AT=2*LbenH - 1.11684/4.;
246  ENDSEQUENCE;
247
248! Put pieces together to form Straight Sections
249  BEAM;
250  SS10   : SEQUENCE, L=2*LstrH;
251    DFH11,             AT=LstrH - 5.7725;
252    QDN11  : QDN1030,  AT=LstrH - (5.1645-.5*dLBmp+.5*dLSext), L=0.5172-dLBmp-dLSext;
253    XDN11,             AT=LstrH - 4.6645;
254    QFN11  : QFN1030,  AT=LstrH - 4.1645,                      L=0.5172-2*dLSext;
255    XFN11,             AT=LstrH - 3.6345;
256    UEH11  : HMONITOR, AT=LstrH - 2.904;
257    UEV11  : VMONITOR, AT=LstrH - 2.814;
258    CtrS10 : MARKER,   AT=LstrH;
259    DHV12,             AT=LstrH + 0.746;
260    UEH12  : HMONITOR, AT=LstrH + 1.3245;
261    UEV12  : VMONITOR, AT=LstrH + 1.4145;
262    XFN12,             AT=LstrH + 3.6345;
263    QFN12  : QFN1030,  AT=LstrH + 4.1645,                      L=0.5172-2*dLSext;
264    XDN12,             AT=LstrH + 4.6645;
265    QDN12  : QDN1030,  AT=LstrH + (5.1645-.5*dLBmp+.5*dLSext), L=0.5172-dLSext-dLBmp;
266    DFH12,             AT=LstrH + 5.7725;
267  ENDSEQUENCE;
268
269  SS20 : SEQUENCE, L=2*LstrH;  !  Note first R than L !!!
270    QFN21  : QFT20,    AT=LstrH - (5.6745+.5*dLBmp),           L=0.5172-dLBmp;
271    DFH21,             AT=LstrH - 5.2145;
272    QDN21  : QDT20,    AT=LstrH - (4.7545-.5*dLBmp+.5*dLSkew), L=0.5172-dLBmp-dLSkew;
273    QSK21,             AT=LstrH - 4.25;
274    QFN23  : QFT23,    AT=LstrH - (3.7545-.5*dLSkew+.5*dLSol), L=0.5172-dLSkew-dLSol;
275    SOL21,             AT=LstrH - 3.124;
276    DEHV21,            AT=LstrH - 2.559;
277    EC0.R  : EC0,      AT=LstrH - 2.465065;
278    ECQSI1,            AT=LstrH - 2.37113;
279    EC1.R  : EC1,      AT=LstrH - 2.128875;
280    ECDH1,             AT=LstrH - 1.88662;
281    EC2.R  : EC2,      AT=LstrH - 1.80873;
282    ECQSI2,            AT=LstrH - 1.73084;
283    EC3.R  : EC3,      AT=LstrH - 1.46492;
284    UEV21  : VMONITOR, AT=LstrH - 1.199;
285    EC4.R  : EC4,      AT=LstrH - 1.144;
286    UEH21  : HMONITOR, AT=LstrH - 1.089;
287    EC5H.R : EC5H,     AT=LstrH - 0.5445;
288    CtrS20 : MARKER,   AT=LstrH;
289    EC5H.L : EC5H,     AT=LstrH + 0.5445;
290    UEH22  : HMONITOR, AT=LstrH + 1.089;
291    EC4.L  : EC4,      AT=LstrH + 1.144;
292    UEV22  : VMONITOR, AT=LstrH + 1.199;
293    EC3.L  : EC3,      AT=LstrH + 1.46492;
294    ECQS02,            AT=LstrH + 1.73084;
295    EC2.L  : EC2,      AT=LstrH + 1.80873;
296    ECDH2,             AT=LstrH + 1.88662;
297    EC1.L  : EC1,      AT=LstrH + 2.128875;
298    ECQS01,            AT=LstrH + 2.37113;
299    EC0.L  : EC0,      AT=LstrH + 2.465065;
300    DEHV22,            AT=LstrH + 2.559;
301    SOL22,             AT=LstrH + 3.124;
302    QFN24  : QFT24,    AT=LstrH + (3.7545-.5*dLSkew+.5*dLSol), L=0.5172-dLSol-dLSkew;
303    QSK22,             AT=LstrH + 4.25;
304    QDN22  : QDT20,    AT=LstrH + (4.7545+.5*dLSkew),          L=0.5172-dLSkew;
305    QFN22  : QFT20,    AT=LstrH + 5.6745,                      L=0.5172;
306  ENDSEQUENCE;
307
308  SS30 : SEQUENCE, L=2*LstrH;
309    QDN31  : QDN1030,  AT=LstrH - (5.1645+.5*dLSext), L=0.5172-dLSext;
310    XDN31,             AT=LstrH - 4.6645;
311    QFN31  : QFN1030,  AT=LstrH - 4.1645,             L=0.5172-2*dLSext;
312    XFN31,             AT=LstrH - 3.6345;
313    KFH31,             AT=LstrH - 3.0085;
314    UEH31  : HMONITOR, AT=LstrH - 2.5735;
315    UEV31  : VMONITOR, AT=LstrH - 2.4835;
316    DHV31,             AT=LstrH - 1.7500;
317
318    CtrS30 : MARKER,   AT=LstrH;
319   
320   
321    UEH32  : HMONITOR, AT=LstrH + 1.6885 -1.0;
322   
323    UEV32  : VMONITOR, AT=LstrH + 1.7785;
324    KFH3234,           AT=LstrH + 2.7585;
325    XFN32,             AT=LstrH + 3.6345;
326    QFN32  : QFN1030,  AT=LstrH + 4.1645,             L=0.5172-2*dLSext;
327    XDN32,             AT=LstrH + 4.6645;
328    QDN32  : QDN1030,  AT=LstrH + (5.1645+.5*dLSext), L=0.5172-dLSext;
329  ENDSEQUENCE;
330
331  SS40 : SEQUENCE, L=2*LstrH;
332    QFN41  : QFN2040,  AT=LstrH - 5.6745,                      L=0.5172;
333    QDN41  : QDN2040,  AT=LstrH - (4.7545+.5*dLSext),          L=0.5172-dLSext;
334    XFLS41,            AT=LstrH - 4.2545;
335    QFN43  : QFN2344,  AT=LstrH - (3.7545-.5*dLSext),          L=0.5172-dLSext;
336    UEH41  : HMONITOR, AT=LstrH - 3.1205;
337    UEV41  : VMONITOR, AT=LstrH - 3.0305;
338    DHV41,             AT=LstrH - 2.8085;
339  !  CRF41,             AT=LstrH - 2.1865;
340 
341    CRF41:  CAV,        AT=LstrH - 2.1865,  L = 1.00;
342 
343    CRF43,             AT=LstrH - 1.0865;
344    CtrS40 : MARKER,   AT=LstrH;
345    DHV42,             AT=LstrH + 1.7425;
346    UEV42  : VMONITOR, AT=LstrH + 1.9645;
347    UEH42  : HMONITOR, AT=LstrH + 2.0545;
348    MSH42,             AT=LstrH + 3.0795;                             ! moved downstream by 3 mm
349    MSV42,             AT=LstrH + 3.2755;                             !   3 mm on Nov. 5th, 2004.
350    QFN44  : QFN2344,  AT=LstrH + (3.7545-.5*dLSext),          L=0.5172-dLSext;
351    XFLS42,            AT=LstrH + 4.2545;
352    QDN42  : QDN2040,  AT=LstrH + (4.7545+.5*dLSext-.5*dLBmp), L=0.5172-dLSext-dLBmp;
353    DFH42,             AT=LstrH + 5.2145;
354    QFN42  : QFN2040,  AT=LstrH + (5.6745+.5*dLBmp),           L=0.5172-dLBmp;
355  ENDSEQUENCE;
356
357! Finally the whole LEIR ring
358  LEIR : SEQUENCE, REFER=CENTRE, L=8*(LstrH + LbenH);
359    SS10,  AT= 0;
360    Arc10, AT= 2*LstrH;
361    SS20,  AT= 2*LstrH + 2*LbenH;
362    Arc20, AT= 4*LstrH + 2*LbenH;
363    SS30,  AT= 4*LstrH + 4*LbenH;
364    Arc30, AT= 6*LstrH + 4*LbenH;
365    SS40,  AT= 6*LstrH + 6*LbenH;
366    Arc40, AT= 8*LstrH + 6*LbenH;
367  ENDSEQUENCE;
368
369
370RETURN;
Note: See TracBrowser for help on using the repository browser.